mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-11-12 12:40:08 +08:00
d1c587a01c
More spec fixes replace process.nextTick with setTimeout(fn, 0) for specs Also added an unspy in the afterEach Temporarily disable specs fix(spec): start fixing specs Summary: This is the WIP fix to our spec runner. Several tests have been completely commented out that will require substantially more work to fix. These have been added to our sprint backlog. Other tests have been fixed to update to new APIs or to deal with genuine bugs that were introduced without our knowing! The most common non-trivial change relates to observing the `NylasAPI` and `NylasAPIRequest`. We used to observe the arguments to `makeRequest`. Unfortunately `NylasAPIRequest.run` is argumentless. Instead you can do: `NylasAPIRequest.prototype.run.mostRecentCall.object.options` to get the `options` passed into the object. the `.object` property grabs the context of the spy when it was last called. Fixing these tests uncovered several concerning issues with our test runner. I spent a while tracking down why our participant-text-field-spec was failling every so often. I chose that spec because it was the first spec to likely fail, thereby requiring looking at the least number of preceding files. I tried binary searching, turning on and off, several files beforehand only to realize that the failure rate was not determined by a particular preceding test, but rather the existing and quantity of preceding tests, AND the number of console.log statements I had. There is some processor-dependent race condition going on that needs further investigation. I also discovered an issue with the file-download-spec. We were getting errors about it accessing a file, which was very suspicious given the code stubs out all fs access. This was caused due to a spec that called an async function outside ot a `waitsForPromise` block or a `waitsFor` block. The test completed, the spies were cleaned up, but the downstream async chain was still running. By the time the async chain finished the runner was already working on the next spec and the spies had been restored (causing the real fs access to run). Juan had an idea to kill the specs once one fails to prevent cascading failures. I'll implement this in the next diff update Test Plan: npm test Reviewers: juan, halla, jackie Differential Revision: https://phab.nylas.com/D3501 Disable other specs Disable more broken specs All specs turned off till passing state Use async-safe versions of spec functions Add async test spec Remove unused package code Remove canary spec
137 lines
6.6 KiB
CoffeeScript
137 lines
6.6 KiB
CoffeeScript
_ = require 'underscore'
|
|
|
|
Actions = require('../../src/flux/actions').default
|
|
Category = require('../../src/flux/models/category').default
|
|
MailboxPerspective = require '../../src/mailbox-perspective'
|
|
|
|
CategoryStore = require '../../src/flux/stores/category-store'
|
|
AccountStore = require('../../src/flux/stores/account-store').default
|
|
FocusedPerspectiveStore = require('../../src/flux/stores/focused-perspective-store').default
|
|
|
|
describe "FocusedPerspectiveStore", ->
|
|
beforeEach ->
|
|
spyOn(FocusedPerspectiveStore, 'trigger')
|
|
FocusedPerspectiveStore._current = MailboxPerspective.forNothing()
|
|
@account = AccountStore.accounts()[0]
|
|
|
|
@inboxCategory = new Category(id: 'id-123', name: 'inbox', displayName: "INBOX", accountId: @account.id)
|
|
@inboxPerspective = MailboxPerspective.forCategory(@inboxCategory)
|
|
@userCategory = new Category(id: 'id-456', name: null, displayName: "MyCategory", accountId: @account.id)
|
|
@userPerspective = MailboxPerspective.forCategory(@userCategory)
|
|
|
|
spyOn(CategoryStore, "getStandardCategory").andReturn @inboxCategory
|
|
spyOn(CategoryStore, "byId").andCallFake (aid, cid) =>
|
|
return {id: 'A'} if aid is 1 and cid is 'A'
|
|
return @inboxCategory if cid is @inboxCategory.id
|
|
return @userCategory if cid is @userCategory.id
|
|
return null
|
|
|
|
describe "_initializeFromSavedState", ->
|
|
beforeEach ->
|
|
@default = MailboxPerspective.forCategory(@inboxCategory)
|
|
spyOn(AccountStore, 'accountIds').andReturn([1, 2])
|
|
spyOn(MailboxPerspective, 'fromJSON').andCallFake (json) -> json
|
|
spyOn(FocusedPerspectiveStore, '_defaultPerspective').andReturn @default
|
|
spyOn(FocusedPerspectiveStore, '_setPerspective')
|
|
|
|
it "uses default perspective when no perspective has been saved", ->
|
|
NylasEnv.savedState.sidebarAccountIds = undefined
|
|
NylasEnv.savedState.perspective = undefined
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(@default, @default.accountIds)
|
|
|
|
it "uses default if the saved perspective has account ids no longer present", ->
|
|
NylasEnv.savedState.sidebarAccountIds = [1, 2, 3]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [1, 2, 3],
|
|
categories: => [{accountId: 1, id: 'A'}],
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(@default, @default.accountIds)
|
|
|
|
NylasEnv.savedState.sidebarAccountIds = [1, 2, 3]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [3]
|
|
categories: => [{accountId: 3, id: 'A'}]
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(@default, @default.accountIds)
|
|
|
|
it "uses default if the saved perspective has category ids no longer present", ->
|
|
NylasEnv.savedState.sidebarAccountIds = [2]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [2]
|
|
categories: => [{accountId: 2, id: 'C'}]
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(@default, @default.accountIds)
|
|
|
|
it "does not honor sidebarAccountIds if it includes account ids no longer present", ->
|
|
NylasEnv.savedState.sidebarAccountIds = [1, 2, 3]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [1]
|
|
categories: => [{accountId: 1, id: 'A'}]
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(NylasEnv.savedState.perspective, [1])
|
|
|
|
it "uses the saved perspective if it is still valid", ->
|
|
NylasEnv.savedState.sidebarAccountIds = [1, 2]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [1, 2]
|
|
categories: => [{accountId: 1, id: 'A'}]
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(NylasEnv.savedState.perspective, [1, 2])
|
|
|
|
NylasEnv.savedState.sidebarAccountIds = [1, 2]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [1]
|
|
categories: => []
|
|
type: 'DraftsMailboxPerspective'
|
|
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(NylasEnv.savedState.perspective, [1, 2])
|
|
|
|
NylasEnv.savedState.sidebarAccountIds = [1]
|
|
NylasEnv.savedState.perspective =
|
|
accountIds: [1]
|
|
categories: => []
|
|
type: 'DraftsMailboxPerspective'
|
|
|
|
FocusedPerspectiveStore._initializeFromSavedState()
|
|
expect(FocusedPerspectiveStore._setPerspective).toHaveBeenCalledWith(NylasEnv.savedState.perspective, [1])
|
|
|
|
describe "_onCategoryStoreChanged", ->
|
|
it "should try to initialize if the curernt perspective hasn't been fully initialized", ->
|
|
spyOn(FocusedPerspectiveStore, '_initializeFromSavedState')
|
|
|
|
FocusedPerspectiveStore._current = @inboxPerspective
|
|
FocusedPerspectiveStore._initialized = true
|
|
FocusedPerspectiveStore._onCategoryStoreChanged()
|
|
expect(FocusedPerspectiveStore._initializeFromSavedState).not.toHaveBeenCalled()
|
|
|
|
FocusedPerspectiveStore._current = MailboxPerspective.forNothing()
|
|
FocusedPerspectiveStore._initialized = false
|
|
FocusedPerspectiveStore._onCategoryStoreChanged()
|
|
expect(FocusedPerspectiveStore._initializeFromSavedState).toHaveBeenCalled()
|
|
|
|
it "should set the current category to default when the current category no longer exists in the CategoryStore", ->
|
|
defaultPerspective = @inboxPerspective
|
|
FocusedPerspectiveStore._initialized = true
|
|
spyOn(FocusedPerspectiveStore, '_defaultPerspective').andReturn(defaultPerspective)
|
|
|
|
otherAccountInbox = @inboxCategory.clone()
|
|
otherAccountInbox.serverId = 'other-id'
|
|
FocusedPerspectiveStore._current = MailboxPerspective.forCategory(otherAccountInbox)
|
|
|
|
FocusedPerspectiveStore._onCategoryStoreChanged()
|
|
expect(FocusedPerspectiveStore.current()).toEqual(defaultPerspective)
|
|
|
|
describe "_onFocusPerspective", ->
|
|
it "should focus the category and trigger", ->
|
|
FocusedPerspectiveStore._onFocusPerspective(@userPerspective)
|
|
expect(FocusedPerspectiveStore.trigger).toHaveBeenCalled()
|
|
expect(FocusedPerspectiveStore.current().categories()).toEqual([@userCategory])
|
|
|
|
describe "_setPerspective", ->
|
|
it "should not trigger if the perspective is already focused", ->
|
|
FocusedPerspectiveStore._setPerspective(@inboxPerspective)
|
|
FocusedPerspectiveStore.trigger.reset()
|
|
FocusedPerspectiveStore._setPerspective(@inboxPerspective)
|
|
expect(FocusedPerspectiveStore.trigger).not.toHaveBeenCalled()
|