mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-11-14 13:44:41 +08:00
89e9cdef8d
Summary: Features: - ThreadListParticipants ignores drafts when computing participants, renders "Draft" label, pending design - Put the WorkspaceStore in every window—means they all get toolbars and custom gumdrop icons on Mac OS X Bug Fixes: - Never display notifications for email the user just sent - Fix obscure issue with DatabaseView trying to update metadata on items it froze. This resolves issue with names remaining bold after marking as read, drafts not appearing in message list immediately. - When you pop out a draft, save it first and *wait* for the commit() promise to succeed. - If you scroll very fast, you node.contentWindow can be null in eventedIframe Other: Make it OK to re-register the same component Make it possible to unregister a hot window Break the Sheet Toolbar out into it's own file to make things manageable Replace `package.windowPropsReceived` with a store-style model where anyone can listen for changes to `windowProps` When I put the WorkspaceStore in every window, I ran into a problem because the package was no longer rendering an instance of the Composer, it was declaring a root sheet with a composer in it. This meant that it was actually a React component that needed to listen to window props, not the package itself. `atom` is already an event emitter, so I added a `onWindowPropsReceived` hook so that components can listen to window props as if they were listening to a store. I think this might be more flexible than only broadcasting the props change event to packages. Test Plan: Run tests Reviewers: evan Reviewed By: evan Differential Revision: https://phab.nylas.com/D1592
105 lines
2.8 KiB
CoffeeScript
105 lines
2.8 KiB
CoffeeScript
React = require 'react'
|
|
_ = require 'underscore'
|
|
{NamespaceStore} = require 'nylas-exports'
|
|
|
|
class ThreadListParticipants extends React.Component
|
|
@displayName: 'ThreadListParticipants'
|
|
|
|
@propTypes:
|
|
thread: React.PropTypes.object.isRequired
|
|
|
|
render: =>
|
|
items = @getParticipants()
|
|
|
|
spans = []
|
|
accumulated = null
|
|
accumulatedUnread = false
|
|
|
|
flush = ->
|
|
if accumulated
|
|
spans.push <span key={spans.length} className="unread-#{accumulatedUnread}">{accumulated}</span>
|
|
accumulated = null
|
|
accumulatedUnread = false
|
|
|
|
accumulate = (text, unread) ->
|
|
if accumulated and unread and accumulatedUnread isnt unread
|
|
flush()
|
|
if accumulated
|
|
accumulated += text
|
|
else
|
|
accumulated = text
|
|
accumulatedUnread = unread
|
|
|
|
for {spacer, contact, unread}, idx in items
|
|
if spacer
|
|
accumulate('...')
|
|
else
|
|
if contact.name.length > 0
|
|
if items.length > 1
|
|
short = contact.displayFirstName()
|
|
else
|
|
short = contact.displayName()
|
|
else
|
|
short = contact.email
|
|
if idx < items.length-1 and not items[idx+1].spacer
|
|
short += ", "
|
|
accumulate(short, unread)
|
|
|
|
if @props.thread.metadata and @props.thread.metadata.length > 1
|
|
accumulate(" (#{@props.thread.metadata.length})")
|
|
|
|
flush()
|
|
|
|
<div className="participants">
|
|
{spans}
|
|
</div>
|
|
|
|
getParticipants: =>
|
|
if @props.thread.metadata
|
|
list = []
|
|
last = null
|
|
for msg in @props.thread.metadata
|
|
continue if msg.draft
|
|
from = msg.from[0]
|
|
if from and from.email isnt last
|
|
list.push({
|
|
contact: msg.from[0]
|
|
unread: msg.unread
|
|
})
|
|
last = from.email
|
|
|
|
else
|
|
list = @props.thread.participants
|
|
return [] unless list and list instanceof Array
|
|
me = NamespaceStore.current().emailAddress
|
|
list = _.reject list, (p) -> p.email is me
|
|
|
|
# Removing "Me" may remove "Me" several times due to the way
|
|
# participants is created. If we're left with an empty array,
|
|
# put one a "Me" back in.
|
|
if list.length is 0 and @props.thread.participants.length > 0
|
|
list.push(@props.thread.participants[0])
|
|
|
|
# Change the list to have the appropriate output format
|
|
list = list.map (contact) ->
|
|
contact: contact
|
|
unread: false # We don't have the data.
|
|
|
|
# We only ever want to show three. Ben...Kevin... Marty
|
|
# But we want the *right* three.
|
|
if list.length > 3
|
|
listTrimmed = []
|
|
|
|
# Always include the first item
|
|
listTrimmed.push(list[0])
|
|
listTrimmed.push({spacer: true})
|
|
|
|
# Always include the last two item
|
|
listTrimmed.push(list[list.length - 2])
|
|
listTrimmed.push(list[list.length - 1])
|
|
list = listTrimmed
|
|
|
|
list
|
|
|
|
|
|
module.exports = ThreadListParticipants
|