mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-09-22 16:26:08 +08:00
523ed4b316
Summary: NamespaceStore needs to be more careful about triggering unnecessarily ThreadListParticipants should use minimum set of <span> tags, not one per name FocusedTagStore triggers only when the tag has actually changed New InboxSyncWorker is responsible for fetching contacts, calendars, threads Update the draft list to look like the thread list ThreadStore now uses a "Database View" to vend items, which will free it up to focus on things like selection soon. The DatabaseView handles pagination and maintains a cache of items in a "retained range" the view needs. It also abstracts the... ..."thread metadata" concept into a general purpose pattern Thread-list package implements SearchView to match the DatabaseView. Instead of fetching items from the database it uses the search API Update existing specs Bug fix Specs for focused stores New specs! Pad search range so we prefetch the next pages Clear the scroll offset if the view is changed (between tabs) Test Plan: Run 58 new tests with 110 new assertions! Reviewers: evan Reviewed By: evan Differential Revision: https://review.inboxapp.com/D1398
107 lines
2.9 KiB
CoffeeScript
107 lines
2.9 KiB
CoffeeScript
React = require 'react'
|
|
_ = require 'underscore-plus'
|
|
{NamespaceStore} = require 'inbox-exports'
|
|
|
|
module.exports =
|
|
ThreadListParticipants = React.createClass
|
|
displayName: 'ThreadListParticipants'
|
|
|
|
propTypes:
|
|
thread: React.PropTypes.object.isRequired
|
|
|
|
render: ->
|
|
items = @getParticipants()
|
|
|
|
spans = []
|
|
accumulated = null
|
|
accumulatedUnread = false
|
|
|
|
flush = ->
|
|
if accumulated
|
|
spans.push <span key={spans.length} className="unread-#{accumulatedUnread}">{accumulated}</span>
|
|
accumulated = null
|
|
accumulatedUnread = false
|
|
|
|
accumulate = (text, unread) ->
|
|
if accumulated and unread and accumulatedUnread isnt unread
|
|
flush()
|
|
if accumulated
|
|
accumulated += text
|
|
else
|
|
accumulated = text
|
|
accumulatedUnread = unread
|
|
|
|
for {spacer, contact, unread}, idx in items
|
|
if spacer
|
|
accumulate('...')
|
|
else
|
|
if contact.name.length > 0
|
|
if items.length > 1
|
|
short = contact.displayFirstName()
|
|
else
|
|
short = contact.displayName()
|
|
else
|
|
short = contact.email
|
|
if idx < items.length-1 and not items[idx+1].spacer
|
|
short += ", "
|
|
accumulate(short, unread)
|
|
|
|
if @props.thread.metadata and @props.thread.metadata.length > 1
|
|
accumulate(" (#{@props.thread.metadata.length})")
|
|
|
|
flush()
|
|
|
|
<div className="participants">
|
|
{spans}
|
|
</div>
|
|
|
|
shouldComponentUpdate: (newProps, newState) ->
|
|
!_.isEqual(newProps.thread, @props.thread)
|
|
|
|
getParticipants: ->
|
|
if @props.thread.metadata
|
|
list = []
|
|
last = null
|
|
for msg in @props.thread.metadata
|
|
from = msg.from[0]
|
|
if from and from.email isnt last
|
|
list.push({
|
|
contact: msg.from[0]
|
|
unread: msg.unread
|
|
})
|
|
last = from.email
|
|
|
|
else
|
|
list = @props.thread.participants
|
|
return [] unless list and list instanceof Array
|
|
me = NamespaceStore.current().emailAddress
|
|
list = _.reject list, (p) -> p.email is me
|
|
|
|
# Removing "Me" may remove "Me" several times due to the way
|
|
# participants is created. If we're left with an empty array,
|
|
# put one a "Me" back in.
|
|
if list.length is 0 and @props.thread.participants.length > 0
|
|
list.push(@props.thread.participants[0])
|
|
|
|
# Change the list to have the appropriate output format
|
|
list = list.map (contact) ->
|
|
contact: contact
|
|
unread: false # We don't have the data.
|
|
|
|
# We only ever want to show three. Ben...Kevin... Marty
|
|
# But we want the *right* three.
|
|
if list.length > 3
|
|
listTrimmed = []
|
|
|
|
# Always include the first item
|
|
listTrimmed.push(list[0])
|
|
listTrimmed.push({spacer: true})
|
|
|
|
# Always include the last two item
|
|
listTrimmed.push(list[list.length - 2])
|
|
listTrimmed.push(list[list.length - 1])
|
|
list = listTrimmed
|
|
|
|
list
|
|
|