mirror of
https://github.com/Foundry376/Mailspring.git
synced 2025-01-23 00:19:58 +08:00
73e7c1c52e
comment Adding test harness Using key strokes in main window test Tests work now Clean up argument variables Rename list manager and get rid of old spec-helper methods Extract out time overrides from spec-helper Spectron test for contenteditable fix spec exit codes and boot mode fix(spec): cleanup N1.sh and make specs fail with exit code 1 Revert tests and get it working in window Move to spec_integration and add window load tester Specs pass. Console logs still in Remove console logs Extract N1 Launcher ready method Make integrated unit test runner feat(tests): adding integration tests Summary: The /spectron folder got moved to /spec_integration There are now unit tests (the old ones) run via the renamed `script/grunt run-unit-tests` There are now integration tests run via the command `script/grunt run-integration-tests`. There are two types of integration tests: 1. Tests that operate on the whole app via Selenium/Chromedriver. These tests have access to Spectron APIs but do NOT have access to any JS object running inside the application. See the `app-boot-spec.es6` for an example of these tests. This is tricky because we want to test the Main window, but Spectron may latch onto any other of our loading windows. Code in `integration-helper` give us an API that finds and loads the main window so we can test it 2. Tests that run in the unit test suite that need Spectron to perform integration-like behavior. These are the contentedtiable specs. The Spectron server is accessed from the app and can be used to trigger actions on the running app, from the app. These tests use the windowed-test runner so Spectron can identify whether the tests have completed, passed, or failed. Unfortunately Spectron can't access the logs , nor the exit code of the test script thereby forcing us to parse the HTML DOM. (Note this is still a WIP) I also revamped the `N1.sh` file when getting the launch arguments to work properly. It's much cleaner. We didn't need most of the data. Test Plan: new tests Reviewers: juan, bengotow Differential Revision: https://phab.nylas.com/D2289 Fix composer specs Tests can properly detect when Spectron is in the environment Report plain text output in specs fixing contenteditable specs Testing slow keymaps on contenteditable specs Move to DOm mutation Spell as `subtree` not `subTree`
110 lines
3 KiB
CoffeeScript
110 lines
3 KiB
CoffeeScript
_ = require 'underscore'
|
|
React = require 'react/addons'
|
|
TimeOverride = require '../../time-override'
|
|
NylasTestUtils = require '../../nylas-test-utils'
|
|
|
|
{Contenteditable} = require 'nylas-component-kit'
|
|
|
|
###
|
|
Public: Easily test contenteditable interactions
|
|
|
|
Create a new instance of this on each test. It will render a new
|
|
Contenteditable into the document wrapped around a class that can keep
|
|
track of its state.
|
|
|
|
For example
|
|
|
|
```coffee
|
|
beforeEach ->
|
|
@ce = new ContenteditableTestHarness
|
|
|
|
it "can create an ordered list", ->
|
|
@ce.keys ['1', '.', ' ']
|
|
@ce.expectHTML "<ol><li></li></ol>"
|
|
@ce.expectSelection (dom) ->
|
|
node: dom.querySelectorAll("li")[0]
|
|
|
|
afterEach ->
|
|
@ce.cleanup()
|
|
|
|
```
|
|
|
|
**Be sure to call `cleanup` after each test**
|
|
|
|
###
|
|
class ContenteditableTestHarness
|
|
constructor: ({@props, @initialValue}={}) ->
|
|
@props ?= {}
|
|
@initialValue ?= ""
|
|
|
|
@wrap = NylasTestUtils.renderIntoDocument(
|
|
<Wrap ceProps={@props} initialValue={@initialValue} />
|
|
)
|
|
|
|
cleanup: ->
|
|
NylasTestUtils.removeFromDocument(@wrap)
|
|
|
|
# We send keys to spectron one at a time. We also need ot use a "real"
|
|
# setTimeout since Spectron is completely outside of the mocked setTimeouts
|
|
# that we setup. We still `advanceClock` to clear any components or Promises
|
|
# that need to run inbetween keystrokes.
|
|
keys: (keyStrokes=[]) -> new Promise (resolve, reject) =>
|
|
TimeOverride.disableSpies()
|
|
@getDOM().focus()
|
|
timeout = 0
|
|
KEY_DELAY = 1000
|
|
keyStrokes.forEach (key) ->
|
|
window.setTimeout ->
|
|
NylasEnv.spectron.client.keys([key])
|
|
advanceClock(KEY_DELAY)
|
|
, timeout
|
|
timeout += KEY_DELAY
|
|
window.setTimeout ->
|
|
resolve()
|
|
, timeout + KEY_DELAY
|
|
|
|
expectHTML: (expectedHTML) ->
|
|
expect(@wrap.state.value).toBe expectedHTML
|
|
|
|
expectSelection: (callback) ->
|
|
expectSel = callback(@getDOM())
|
|
|
|
anchorNode = expectSel.anchorNode ? expectSel.node ? "No anchorNode found"
|
|
focusNode = expectSel.focusNode ? expectSel.node ? "No focusNode found"
|
|
anchorOffset = expectSel.anchorOffset ? expectSel.offset ? 0
|
|
focusOffset = expectSel.focusOffset ? expectSel.offset ? 0
|
|
|
|
selection = document.getSelection()
|
|
|
|
expect(selection.anchorNode).toBe anchorNode
|
|
expect(selection.focusNode).toBe focusNode
|
|
expect(selection.anchorOffset).toBe anchorOffset
|
|
expect(selection.focusOffset).toBe focusOffset
|
|
|
|
getDOM: ->
|
|
React.findDOMNode(@wrap.refs["ceWrap"].refs["contenteditable"])
|
|
|
|
class Wrap extends React.Component
|
|
@displayName: "wrap"
|
|
|
|
constructor: (@props) ->
|
|
@state = value: @props.initialValue
|
|
|
|
render: ->
|
|
userOnChange = @props.ceProps.onChange ? ->
|
|
props = _.clone(@props.ceProps)
|
|
props.onChange = (event) =>
|
|
userOnChange(event)
|
|
@onChange(event)
|
|
props.value = @state.value
|
|
props.ref = "ceWrap"
|
|
|
|
<Contenteditable {...props} />
|
|
|
|
onChange: (event) ->
|
|
@setState value: event.target.value
|
|
|
|
componentDidMount: ->
|
|
@refs.ceWrap.focus()
|
|
|
|
module.exports = ContenteditableTestHarness
|