mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-09-22 08:16:09 +08:00
9d995ded67
Summary: Move sync workers and Edgehill token checks to work window Move the task queue and database setup to the work window Move ContactStore background refresh to work window Store the task queue in the database WIP The TaskQueue now puts tasks in the database instead of in a file, which also means it can be observed Move all delta sync and initial sync to a package, make NylasSyncStore which exposes read-only sync state DraftStore no longer reads task status. Once you set the "sending" bit on a draft, it never gets unset. But that's fine actually. If your package lists windowTypes, you *only* get loaded in those windowTypes. If you specify no windowTypes, you get loaded in the root window. This means that onboarding, worker-ui, worker-sync, etc. no longer get loaded into the main window ActivitySidebar has a special little store that observes the task queue since it's no longer in the window Move "toggle component regions" / "toggle react remote" to the Developer menu Move sync worker specs, update draft store specs to not rely on TaskQueue at all Test Plan: Run existing tests, all pass Reviewers: dillon, evan Reviewed By: evan Differential Revision: https://phab.nylas.com/D1936
120 lines
3.2 KiB
CoffeeScript
120 lines
3.2 KiB
CoffeeScript
React = require 'react'
|
|
_ = require 'underscore'
|
|
classNames = require 'classnames'
|
|
NotificationStore = require './notifications-store'
|
|
{Actions,
|
|
TaskQueue,
|
|
AccountStore,
|
|
NylasSyncStatusStore,
|
|
TaskQueueStatusStore,
|
|
NylasAPI} = require 'nylas-exports'
|
|
{TimeoutTransitionGroup} = require 'nylas-component-kit'
|
|
|
|
class ActivitySidebar extends React.Component
|
|
@displayName: 'ActivitySidebar'
|
|
|
|
@containerRequired: false
|
|
@containerStyles:
|
|
minWidth: 165
|
|
maxWidth: 400
|
|
|
|
constructor: (@props) ->
|
|
@state = @_getStateFromStores()
|
|
|
|
componentDidMount: =>
|
|
@_unlisteners = []
|
|
@_unlisteners.push TaskQueueStatusStore.listen @_onDataChanged
|
|
@_unlisteners.push NylasSyncStatusStore.listen @_onDataChanged
|
|
@_unlisteners.push NotificationStore.listen @_onDataChanged
|
|
|
|
componentWillUnmount: =>
|
|
unlisten() for unlisten in @_unlisteners
|
|
@_workerUnlisten() if @_workerUnlisten
|
|
|
|
render: =>
|
|
items = [].concat(@_renderSyncActivityItem(), @_renderNotificationActivityItems(), @_renderTaskActivityItems())
|
|
|
|
names = classNames
|
|
"sidebar-activity": true
|
|
"sidebar-activity-empty": items.length is 0
|
|
"sidebar-activity-error": error?
|
|
|
|
<TimeoutTransitionGroup
|
|
className={names}
|
|
leaveTimeout={625}
|
|
enterTimeout={125}
|
|
transitionName="activity-item">
|
|
{items}
|
|
</TimeoutTransitionGroup>
|
|
|
|
_renderSyncActivityItem: =>
|
|
count = 0
|
|
fetched = 0
|
|
progress = 0
|
|
incomplete = 0
|
|
error = null
|
|
|
|
for acctId, state of @state.sync
|
|
for model, modelState of state
|
|
incomplete += 1 unless modelState.complete
|
|
error ?= modelState.error
|
|
if modelState.count
|
|
count += modelState.count / 1
|
|
fetched += modelState.fetched / 1
|
|
|
|
progress = (fetched / count) * 100 if count > 0
|
|
|
|
if incomplete is 0
|
|
return []
|
|
else if error
|
|
<div className="item" key="initial-sync">
|
|
<div className="inner">Initial sync encountered an error. Waiting to retry...
|
|
<div className="btn btn-emphasis" onClick={@_onTryAgain}>Try Again</div>
|
|
</div>
|
|
</div>
|
|
else
|
|
<div className="item" key="initial-sync">
|
|
<div className="progress-track">
|
|
<div className="progress" style={width: "#{progress}%"}></div>
|
|
</div>
|
|
<div className="inner">Syncing mail data...</div>
|
|
</div>
|
|
|
|
_renderTaskActivityItems: =>
|
|
summary = {}
|
|
|
|
@state.tasks.map (task) ->
|
|
label = task.label?()
|
|
return unless label
|
|
summary[label] ?= 0
|
|
summary[label] += 1
|
|
|
|
_.pairs(summary).map ([label, count]) ->
|
|
<div className="item" key={label}>
|
|
<div className="inner">
|
|
{label} <span className="count">({count})</span>
|
|
</div>
|
|
</div>
|
|
|
|
_renderNotificationActivityItems: =>
|
|
@state.notifications.map (notification) ->
|
|
<div className="item" key={notification.id}>
|
|
<div className="inner">
|
|
{notification.message}
|
|
</div>
|
|
</div>
|
|
|
|
_onTryAgain: =>
|
|
# TODO
|
|
|
|
_onDataChanged: =>
|
|
@setState(@_getStateFromStores())
|
|
|
|
_getStateFromStores: =>
|
|
notifications: NotificationStore.notifications()
|
|
tasks: TaskQueueStatusStore.queue()
|
|
sync: NylasSyncStatusStore.state()
|
|
|
|
|
|
module.exports = ActivitySidebar
|