mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-09-22 16:26:08 +08:00
44a7fa7117
Summary: This commit adds a couple of missing assets, including the icon for the plugin list and other misc icons. It also switches to the new UI where we use the thread timestamps to display the reminder date in the Reminders perspective instead of using mail labels. It also adds a header to the threads inside the reminders perspective to indicate that a reminder will be triggered if no one replies to their email. It also adds a header to indicate when a message has been brought back to the inbox due to a reminder based on sdw's designs. Finally it restores some code that magically disappeared when landing reminders + other misc cleanup Test Plan: Manual Reviewers: bengotow, halla Reviewed By: bengotow, halla Differential Revision: https://phab.nylas.com/D3388
93 lines
2.4 KiB
CoffeeScript
93 lines
2.4 KiB
CoffeeScript
React = require 'react'
|
|
classNames = require 'classnames'
|
|
|
|
MessageItem = require './message-item'
|
|
|
|
{Utils,
|
|
DraftStore,
|
|
ComponentRegistry,
|
|
MessageStore} = require 'nylas-exports'
|
|
|
|
|
|
class MessageItemContainer extends React.Component
|
|
@displayName = 'MessageItemContainer'
|
|
|
|
@propTypes =
|
|
thread: React.PropTypes.object.isRequired
|
|
message: React.PropTypes.object.isRequired
|
|
messages: React.PropTypes.array.isRequired
|
|
collapsed: React.PropTypes.bool
|
|
isLastMsg: React.PropTypes.bool
|
|
isBeforeReplyArea: React.PropTypes.bool
|
|
scrollTo: React.PropTypes.func
|
|
|
|
constructor: (@props) ->
|
|
@state = @_getStateFromStores()
|
|
|
|
componentWillReceiveProps: (newProps) ->
|
|
@setState(@_getStateFromStores(newProps))
|
|
|
|
componentDidMount: =>
|
|
if @props.message.draft
|
|
@_unlisten = DraftStore.listen @_onSendingStateChanged
|
|
|
|
shouldComponentUpdate: (nextProps, nextState) =>
|
|
not Utils.isEqualReact(nextProps, @props) or
|
|
not Utils.isEqualReact(nextState, @state)
|
|
|
|
componentWillUnmount: =>
|
|
@_unlisten() if @_unlisten
|
|
|
|
focus: =>
|
|
@refs.message.focus()
|
|
|
|
render: =>
|
|
if @state.isSending
|
|
@_renderMessage(pending: true)
|
|
else if @props.message.draft
|
|
@_renderComposer()
|
|
else
|
|
@_renderMessage(pending: false)
|
|
|
|
_renderMessage: ({pending}) =>
|
|
<MessageItem
|
|
ref="message"
|
|
pending={pending}
|
|
thread={@props.thread}
|
|
message={@props.message}
|
|
messages={@props.messages}
|
|
className={@_classNames()}
|
|
collapsed={@props.collapsed}
|
|
isLastMsg={@props.isLastMsg}
|
|
/>
|
|
|
|
_renderComposer: =>
|
|
Composer = ComponentRegistry.findComponentsMatching(role: 'Composer')[0]
|
|
if (!Composer)
|
|
return <span></span>
|
|
|
|
<Composer
|
|
ref="message"
|
|
draftClientId={@props.message.clientId}
|
|
className={@_classNames()}
|
|
mode={"inline"}
|
|
threadId={@props.thread.id}
|
|
scrollTo={@props.scrollTo}
|
|
/>
|
|
|
|
_classNames: => classNames
|
|
"draft": @props.message.draft
|
|
"unread": @props.message.unread
|
|
"collapsed": @props.collapsed
|
|
"message-item-wrap": true
|
|
"before-reply-area": @props.isBeforeReplyArea
|
|
|
|
_onSendingStateChanged: (draftClientId) =>
|
|
if draftClientId is @props.message.clientId
|
|
@setState(@_getStateFromStores())
|
|
|
|
_getStateFromStores: (props = @props) ->
|
|
isSending: DraftStore.isSendingDraft(props.message.clientId)
|
|
|
|
module.exports = MessageItemContainer
|