mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-09-24 09:16:07 +08:00
8133cc88d6
Summary: - We now make verbose log files continuously as you use the app - We ship the logs to LogStash via S3 when an exception occurs - We log the DatabaseStore, ActionBridge and Analytics packages - We are now on the latest version of Electron 0.26.0 - We are now on Chrome 42 and io.js 1.4.3 - We should be setup to use ASAR soon. Update atom.sh to reflect that we're now electron oniguruma was unnecessary correctly find log files that haven't been shipped yet Fix a small issue with nodeIsVisible after upgrade to Chrome 42 Delete old logs, better logging from database store, don't ship empty logs Test Plan: Run existing tests Reviewers: evan Reviewed By: evan Differential Revision: https://phab.nylas.com/D1531
110 lines
3.5 KiB
CoffeeScript
110 lines
3.5 KiB
CoffeeScript
_ = require 'underscore'
|
|
_ = _.extend(_, require('./space-pen-utils'))
|
|
SpacePen = require 'space-pen'
|
|
{Subscriber} = require 'emissary'
|
|
|
|
###
|
|
Edgehill Note:
|
|
|
|
I want this file gone—plan is to slowly delete stuff below as we clean spacepen
|
|
and it's helpers out of the project.
|
|
|
|
- Ben
|
|
###
|
|
|
|
|
|
Subscriber.includeInto(SpacePen.View)
|
|
|
|
jQuery = SpacePen.jQuery
|
|
JQueryCleanData = jQuery.cleanData
|
|
jQuery.cleanData = (elements) ->
|
|
jQuery(element).view()?.unsubscribe?() for element in elements
|
|
JQueryCleanData(elements)
|
|
|
|
SpacePenCallRemoveHooks = SpacePen.callRemoveHooks
|
|
SpacePen.callRemoveHooks = (element) ->
|
|
view.unsubscribe?() for view in SpacePen.viewsForElement(element)
|
|
SpacePenCallRemoveHooks(element)
|
|
|
|
NativeEventNames = new Set
|
|
NativeEventNames.add(nativeEvent) for nativeEvent in ["blur", "focus", "focusin",
|
|
"focusout", "load", "resize", "scroll", "unload", "click", "dblclick", "mousedown",
|
|
"mouseup", "mousemove", "mouseover", "mouseout", "mouseenter", "mouseleave", "change",
|
|
"select", "submit", "keydown", "keypress", "keyup", "error", "contextmenu", "textInput",
|
|
"textinput", "beforeunload"]
|
|
|
|
JQueryTrigger = jQuery.fn.trigger
|
|
jQuery.fn.trigger = (eventName, data) ->
|
|
if NativeEventNames.has(eventName) or typeof eventName is 'object'
|
|
JQueryTrigger.call(this, eventName, data)
|
|
else
|
|
data ?= {}
|
|
data.jQueryTrigger = true
|
|
|
|
for element in this
|
|
atom.commands.dispatch(element, eventName, data)
|
|
this
|
|
|
|
HandlersByOriginalHandler = new WeakMap
|
|
CommandDisposablesByElement = new WeakMap
|
|
|
|
AddEventListener = (element, type, listener) ->
|
|
if NativeEventNames.has(type)
|
|
element.addEventListener(type, listener)
|
|
else
|
|
disposable = atom.commands.add(element, type, listener)
|
|
|
|
unless disposablesByType = CommandDisposablesByElement.get(element)
|
|
disposablesByType = {}
|
|
CommandDisposablesByElement.set(element, disposablesByType)
|
|
|
|
unless disposablesByListener = disposablesByType[type]
|
|
disposablesByListener = new WeakMap
|
|
disposablesByType[type] = disposablesByListener
|
|
|
|
disposablesByListener.set(listener, disposable)
|
|
|
|
RemoveEventListener = (element, type, listener) ->
|
|
if NativeEventNames.has(type)
|
|
element.removeEventListener(type, listener)
|
|
else
|
|
CommandDisposablesByElement.get(element)?[type]?.get(listener)?.dispose()
|
|
|
|
JQueryEventAdd = jQuery.event.add
|
|
jQuery.event.add = (elem, types, originalHandler, data, selector) ->
|
|
handler = (event) ->
|
|
if arguments.length is 1 and event.originalEvent?.detail?
|
|
{detail} = event.originalEvent
|
|
if Array.isArray(detail)
|
|
originalHandler.apply(this, [event].concat(detail))
|
|
else
|
|
originalHandler.call(this, event, detail)
|
|
else
|
|
originalHandler.apply(this, arguments)
|
|
|
|
HandlersByOriginalHandler.set(originalHandler, handler)
|
|
|
|
JQueryEventAdd.call(this, elem, types, handler, data, selector, AddEventListener if atom?.commands?)
|
|
|
|
JQueryEventRemove = jQuery.event.remove
|
|
jQuery.event.remove = (elem, types, originalHandler, selector, mappedTypes) ->
|
|
if originalHandler?
|
|
handler = HandlersByOriginalHandler.get(originalHandler) ? originalHandler
|
|
JQueryEventRemove(elem, types, handler, selector, mappedTypes, RemoveEventListener if atom?.commands?)
|
|
|
|
JQueryContains = jQuery.contains
|
|
|
|
jQuery.contains = (a, b) ->
|
|
shadowRoot = null
|
|
currentNode = b
|
|
while currentNode
|
|
if currentNode instanceof ShadowRoot and a.contains(currentNode.host)
|
|
return true
|
|
currentNode = currentNode.parentNode
|
|
|
|
JQueryContains.call(this, a, b)
|
|
|
|
Object.defineProperty jQuery.fn, 'element', get: -> @[0]
|
|
|
|
module.exports = SpacePen
|