mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-11-14 13:44:41 +08:00
9d995ded67
Summary: Move sync workers and Edgehill token checks to work window Move the task queue and database setup to the work window Move ContactStore background refresh to work window Store the task queue in the database WIP The TaskQueue now puts tasks in the database instead of in a file, which also means it can be observed Move all delta sync and initial sync to a package, make NylasSyncStore which exposes read-only sync state DraftStore no longer reads task status. Once you set the "sending" bit on a draft, it never gets unset. But that's fine actually. If your package lists windowTypes, you *only* get loaded in those windowTypes. If you specify no windowTypes, you get loaded in the root window. This means that onboarding, worker-ui, worker-sync, etc. no longer get loaded into the main window ActivitySidebar has a special little store that observes the task queue since it's no longer in the window Move "toggle component regions" / "toggle react remote" to the Developer menu Move sync worker specs, update draft store specs to not rely on TaskQueue at all Test Plan: Run existing tests, all pass Reviewers: dillon, evan Reviewed By: evan Differential Revision: https://phab.nylas.com/D1936
55 lines
1.7 KiB
CoffeeScript
55 lines
1.7 KiB
CoffeeScript
React = require 'react/addons'
|
|
classNames = require 'classnames'
|
|
_ = require 'underscore'
|
|
{Utils} = require 'nylas-exports'
|
|
|
|
class DeveloperBarTask extends React.Component
|
|
@displayName: 'DeveloperBarTask'
|
|
|
|
constructor: (@props) ->
|
|
@state = expanded: false
|
|
|
|
render: =>
|
|
<div className={@_classNames()} onClick={=> @setState expanded: not @state.expanded}>
|
|
<div className="task-summary">
|
|
{@_taskSummary()}
|
|
</div>
|
|
<div className="task-details">
|
|
{JSON.stringify(@props.task.toJSON())}
|
|
</div>
|
|
</div>
|
|
|
|
shouldComponentUpdate: (nextProps, nextState) =>
|
|
return not Utils.isEqualReact(nextProps, @props) or not Utils.isEqualReact(nextState, @state)
|
|
|
|
_taskSummary: =>
|
|
qs = @props.task.queueState
|
|
errType = ""
|
|
errCode = ""
|
|
errMessage = ""
|
|
if qs.localError?
|
|
localError = qs.localError
|
|
errType = localError.constructor.name
|
|
errMessage = localError.message ? JSON.stringify(localError)
|
|
else if qs.remoteError?
|
|
remoteError = qs.remoteError
|
|
errType = remoteError.constructor.name
|
|
errCode = remoteError.statusCode ? ""
|
|
errMessage = remoteError.body?.message ? remoteError?.message ? JSON.stringify(remoteError)
|
|
|
|
return "#{@props.task.constructor.name} #{errType} #{errCode} #{errMessage}"
|
|
|
|
_classNames: =>
|
|
qs = @props.task.queueState ? {}
|
|
classNames
|
|
"task": true
|
|
"task-queued": @props.type is "queued"
|
|
"task-completed": @props.type is "completed"
|
|
"task-expanded": @state.expanded
|
|
"task-local-error": qs.localError
|
|
"task-remote-error": qs.remoteError
|
|
"task-is-processing": qs.isProcessing
|
|
"task-success": qs.localComplete and qs.remoteComplete
|
|
|
|
|
|
module.exports = DeveloperBarTask
|