mirror of
https://github.com/Foundry376/Mailspring.git
synced 2024-09-22 16:26:08 +08:00
cd9ccd85e2
Summary: WIP. The app launches and works for me. I still need to fix the tests just the DB ones though :D I changed the `DatabaseProxy` into a `DatabaseConnection` object. It will request a fully instantiated databse from the backend Browser. If we're already setup, it'll connect straight to the existing DB. If we're not setup, then it'll create a new database and run the inital schema migration on it. The `_createNewDatabase` promise won't resolve until the migration has run. Until we add in a more sophisticated migration system and get rid of the stupid `modelClassMap` that's shoved in `Utils`, I'm passing in a series of `_setupQueries()` to get everything started. The `DatabaseConnection` is also the one responsible for queuing up queries until the DB is fully populated and ready to go. We actually get a lot of queries before we're setup because a lot of Stores will make DB requests on `require` in their `constructor` or `init` methods. (remember all the times we call `_populateStore` in `init`). Now those queries are aggregated by the `DatabaseConnection` and then executed sequentially. Our methods like `persistModel` now resolve only after both the queries have completed AND their corresponding `triggerLater` has completed as well. Test Plan: in progress Reviewers: bengotow Reviewed By: bengotow Differential Revision: https://phab.nylas.com/D1688
86 lines
2.8 KiB
CoffeeScript
86 lines
2.8 KiB
CoffeeScript
File = require '../../src/flux/models/file'
|
|
Actions = require '../../src/flux/actions'
|
|
FileUploadStore = require '../../src/flux/stores/file-upload-store'
|
|
|
|
msgId = "local-123"
|
|
fpath = "/foo/bar/test123.jpg"
|
|
|
|
describe 'FileUploadStore', ->
|
|
beforeEach ->
|
|
@file = new File
|
|
id: "id_123"
|
|
filename: "test123.jpg"
|
|
size: 12345
|
|
@uploadData =
|
|
uploadId: 123
|
|
messageLocalId: msgId
|
|
filePath: fpath
|
|
fileSize: 12345
|
|
|
|
spyOn(atom, "showOpenDialog").andCallFake (props, callback) ->
|
|
callback(fpath)
|
|
|
|
spyOn(Actions, "queueTask")
|
|
|
|
describe 'when a user wants to attach a file', ->
|
|
it "throws if the message id is blank", ->
|
|
expect( -> Actions.attachFile()).toThrow()
|
|
|
|
it "throws if the message id is blank", ->
|
|
spyOn(Actions, "attachFilePath")
|
|
Actions.attachFile messageLocalId: msgId
|
|
expect(atom.showOpenDialog).toHaveBeenCalled()
|
|
expect(Actions.attachFilePath).toHaveBeenCalled()
|
|
args = Actions.attachFilePath.calls[0].args[0]
|
|
expect(args.messageLocalId).toBe msgId
|
|
expect(args.path).toBe fpath
|
|
|
|
describe 'when a user selected the file to attach', ->
|
|
it "throws if the message id is blank", ->
|
|
expect( -> Actions.attachFilePath()).toThrow()
|
|
|
|
it 'Creates a new file upload task', ->
|
|
Actions.attachFilePath
|
|
messageLocalId: msgId
|
|
path: fpath
|
|
expect(Actions.queueTask).toHaveBeenCalled()
|
|
t = Actions.queueTask.calls[0].args[0]
|
|
expect(t.filePath).toBe fpath
|
|
expect(t.messageLocalId).toBe msgId
|
|
|
|
describe 'when an uploading file is aborted', ->
|
|
it "dequeues the matching task", ->
|
|
spyOn(Actions, "dequeueMatchingTask")
|
|
Actions.abortUpload(@uploadData)
|
|
expect(Actions.dequeueMatchingTask).toHaveBeenCalled()
|
|
arg = Actions.dequeueMatchingTask.calls[0].args[0]
|
|
expect(arg).toEqual
|
|
type: "FileUploadTask"
|
|
matching: filePath: fpath
|
|
|
|
describe 'when upload state changes', ->
|
|
it 'updates the uploadData', ->
|
|
Actions.uploadStateChanged(@uploadData)
|
|
expect(FileUploadStore._fileUploads[123]).toBe @uploadData
|
|
|
|
describe 'when a file has been uploaded', ->
|
|
it 'adds removes from uploads', ->
|
|
FileUploadStore._fileUploads[123] = @uploadData
|
|
Actions.fileUploaded
|
|
file: @file
|
|
uploadData: @uploadData
|
|
expect(FileUploadStore._fileUploads[123]).not.toBeDefined()
|
|
|
|
it 'adds to the linked files', ->
|
|
FileUploadStore._fileUploads[123] = @uploadData
|
|
Actions.linkFileToUpload
|
|
file: @file
|
|
uploadData: @uploadData
|
|
expect(FileUploadStore._linkedFiles["id_123"]).toBe @uploadData
|
|
|
|
describe 'when a file has been aborted', ->
|
|
it 'removes it from the uploads', ->
|
|
FileUploadStore._fileUploads[123] = @uploadData
|
|
Actions.fileAborted(@uploadData)
|
|
expect(FileUploadStore._fileUploads[123]).not.toBeDefined()
|