proxmark3/armsrc/ldscript

/*
-----------------------------------------------------------------------------
 This code is licensed to you under the terms of the GNU GPL, version 2 or,
 at your option, any later version. See the LICENSE.txt file for the text of
 the license.
-----------------------------------------------------------------------------
 Linker script for the ARM binary
-----------------------------------------------------------------------------
*/
INCLUDE ../common/ldscript.common

ENTRY(Vector)
SECTIONS
{
	.fpgaimage : {
		*(fpga_bit.data)
	} >fpgaimage
	.start : { *(.startos) } >osimage
	.text : { 
		*(.text)
		*(.text.*)
		*(.eh_frame)
		*(.glue_7)
		*(.glue_7t)
		*(.rodata) 
		*(.rodata*) 
		*(.version_information)
	} >osimage
	__end_of_text__ = .;
	
	.data : {
		__data_start__ = .;
		__data_src_start__ = __end_of_text__; 
		*(.data)
		*(.data.*)
		__data_end__ = .;
	} >ram AT>osimage
	
	.bss : {
		__bss_start__ = .; 
		*(.bss)
		*(.bss.*) 
	} >ram
	. = ALIGN(32 / 8);
	__bss_end__ = .;

    	.commonarea (NOLOAD) : {
    		*(.commonarea)
    	} >commonarea
}