mirror of
https://github.com/RfidResearchGroup/proxmark3.git
synced 2024-09-20 15:26:13 +08:00
d19754567d
* .h include only the strict minimum for their own parsing * this forces all files to include explicitment their needs and not count on far streched dependencies * this helps Makefile to rebuild only the minimum * according to this rule, most standalone .h are now gone * big app.h is gone * remove seldom __cplusplus, if c++ happens, everything will have to be done properly anyway * all unrequired include were removed * split common/ into common/ (client+arm) and common_arm/ (os+bootloader) * bring zlib to common/ * bring stuff not really/not yet used in common back to armsrc/ or client/ * bring liblua into client/ * bring uart into client/ * move some portions of code around (dbprint, protocols,...) * rename unused files into *_disabled.[ch] to make it explicit * rename soft Uarts between 14a, 14b and iclass, so a standalone could use several without clash * remove PrintAndLogDevice * move deprecated-hid-flasher from client to tools * Makefiles * treat deps in armsrc/ as in client/ * client: stop on warning (-Werror), same as for armsrc/ Tested on: * all standalone modes * Linux
68 lines
1.5 KiB
Plaintext
68 lines
1.5 KiB
Plaintext
/*
|
|
-----------------------------------------------------------------------------
|
|
This code is licensed to you under the terms of the GNU GPL, version 2 or,
|
|
at your option, any later version. See the LICENSE.txt file for the text of
|
|
the license.
|
|
-----------------------------------------------------------------------------
|
|
Linker script for the ARM binary
|
|
-----------------------------------------------------------------------------
|
|
*/
|
|
INCLUDE ../common_arm/ldscript.common
|
|
|
|
PHDRS
|
|
{
|
|
text PT_LOAD FLAGS(5);
|
|
data PT_LOAD;
|
|
bss PT_LOAD;
|
|
}
|
|
|
|
ENTRY(Vector)
|
|
SECTIONS
|
|
{
|
|
.start : {
|
|
*(.startos)
|
|
} >osimage :text
|
|
|
|
.text : {
|
|
KEEP(*(stage1_image))
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.eh_frame)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
} >osimage :text
|
|
|
|
.rodata : {
|
|
*(.rodata)
|
|
*(.rodata.*)
|
|
*(fpga_all_bit.data)
|
|
KEEP(*(.version_information))
|
|
. = ALIGN(8);
|
|
} >osimage :text
|
|
|
|
.data : {
|
|
KEEP(*(compressed_data))
|
|
*(.data)
|
|
*(.data.*)
|
|
*(.ramfunc)
|
|
. = ALIGN(4);
|
|
} >ram AT>osimage :data
|
|
|
|
__data_src_start__ = LOADADDR(.data);
|
|
__data_start__ = ADDR(.data);
|
|
__data_end__ = __data_start__ + SIZEOF(.data);
|
|
__os_size__ = SIZEOF(.text) + SIZEOF(.data) + SIZEOF(.rodata);
|
|
|
|
.bss : {
|
|
__bss_start__ = .;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
. = ALIGN(4);
|
|
__bss_end__ = .;
|
|
} >ram AT>ram :bss
|
|
|
|
.commonarea (NOLOAD) : {
|
|
*(.commonarea)
|
|
} >commonarea :NONE
|
|
}
|