mirror of
https://github.com/RfidResearchGroup/proxmark3.git
synced 2024-09-20 23:36:31 +08:00
d19754567d
* .h include only the strict minimum for their own parsing * this forces all files to include explicitment their needs and not count on far streched dependencies * this helps Makefile to rebuild only the minimum * according to this rule, most standalone .h are now gone * big app.h is gone * remove seldom __cplusplus, if c++ happens, everything will have to be done properly anyway * all unrequired include were removed * split common/ into common/ (client+arm) and common_arm/ (os+bootloader) * bring zlib to common/ * bring stuff not really/not yet used in common back to armsrc/ or client/ * bring liblua into client/ * bring uart into client/ * move some portions of code around (dbprint, protocols,...) * rename unused files into *_disabled.[ch] to make it explicit * rename soft Uarts between 14a, 14b and iclass, so a standalone could use several without clash * remove PrintAndLogDevice * move deprecated-hid-flasher from client to tools * Makefiles * treat deps in armsrc/ as in client/ * client: stop on warning (-Werror), same as for armsrc/ Tested on: * all standalone modes * Linux
64 lines
1.4 KiB
Plaintext
64 lines
1.4 KiB
Plaintext
/*
|
|
-----------------------------------------------------------------------------
|
|
This code is licensed to you under the terms of the GNU GPL, version 2 or,
|
|
at your option, any later version. See the LICENSE.txt file for the text of
|
|
the license.
|
|
-----------------------------------------------------------------------------
|
|
Bootrom linker script
|
|
-----------------------------------------------------------------------------
|
|
*/
|
|
|
|
INCLUDE ../common_arm/ldscript.common
|
|
|
|
PHDRS
|
|
{
|
|
phase1 PT_LOAD;
|
|
phase2 PT_LOAD;
|
|
bss PT_LOAD;
|
|
}
|
|
|
|
ENTRY(flashstart)
|
|
SECTIONS
|
|
{
|
|
.bootphase1 : {
|
|
*(.startup)
|
|
|
|
. = ALIGN(4);
|
|
_version_information_start = .;
|
|
KEEP(*(.version_information));
|
|
|
|
. = LENGTH(bootphase1) - 0x4;
|
|
LONG(_version_information_start);
|
|
} >bootphase1 :phase1
|
|
|
|
.bootphase2 : {
|
|
*(.startphase2)
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.eh_frame)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.rodata)
|
|
*(.rodata.*)
|
|
*(.data)
|
|
*(.data.*)
|
|
. = ALIGN(4);
|
|
} >ram AT>bootphase2 :phase2
|
|
|
|
__bootphase2_src_start__ = LOADADDR(.bootphase2);
|
|
__bootphase2_start__ = ADDR(.bootphase2);
|
|
__bootphase2_end__ = __bootphase2_start__ + SIZEOF(.bootphase2);
|
|
|
|
.bss : {
|
|
__bss_start__ = .;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
. = ALIGN(4);
|
|
__bss_end__ = .;
|
|
} >ram AT>ram :bss
|
|
|
|
.commonarea (NOLOAD) : {
|
|
*(.commonarea)
|
|
} >commonarea
|
|
}
|