mirror of
https://github.com/livebook-dev/livebook.git
synced 2024-09-21 18:35:59 +08:00
bd8e06b5ce
* Use live redirect for local links in rendered markdown * Resolve relative notebook URLs * Bump LV * Adds tests * Handle nested relative path * Handle child nested paths
46 lines
1.4 KiB
Elixir
46 lines
1.4 KiB
Elixir
defmodule LivebookWeb.SessionHelpers do
|
|
import Phoenix.LiveView
|
|
alias LivebookWeb.Router.Helpers, as: Routes
|
|
|
|
@doc """
|
|
Creates a new session, redirects on success,
|
|
puts an error flash message on failure.
|
|
|
|
Accepts the same options as `Livebook.SessionSupervisor.create_session/1`.
|
|
"""
|
|
@spec create_session(Phoenix.LiveView.Socket.t(), keyword()) :: Phoenix.LiveView.Socket.t()
|
|
def create_session(socket, opts \\ []) do
|
|
case Livebook.SessionSupervisor.create_session(opts) do
|
|
{:ok, id} ->
|
|
push_redirect(socket, to: Routes.session_path(socket, :page, id))
|
|
|
|
{:error, reason} ->
|
|
put_flash(socket, :error, "Failed to create session: #{reason}")
|
|
end
|
|
end
|
|
|
|
@doc """
|
|
Formats the given list of notebook import messages and puts
|
|
into the info flash.
|
|
"""
|
|
@spec put_import_flash_messages(Phoenix.LiveView.Socket.t(), list(String.t())) ::
|
|
Phoenix.LiveView.Socket.t()
|
|
def put_import_flash_messages(socket, messages)
|
|
|
|
def put_import_flash_messages(socket, []), do: socket
|
|
|
|
def put_import_flash_messages(socket, messages) do
|
|
list =
|
|
messages
|
|
|> Enum.map(fn message -> ["- ", message] end)
|
|
|> Enum.intersperse("\n")
|
|
|
|
flash =
|
|
IO.iodata_to_binary([
|
|
"We found problems while importing the file and tried to autofix them:\n" | list
|
|
])
|
|
|
|
put_flash(socket, :info, flash)
|
|
end
|
|
end
|